Описание скритового языка программы IFS Builder 3d

• Общий вид ifs-файла
• Пример: Снежинка Коха
• Множества и отображения
• Базовые отображения множеств
• Камера
• Освещённость
  • 1. Параметры освещенности сцены
  • 2. Источники света
  • 3. Отражающие свойства поверхностей
• Подстановки
• Арифметические выражения
• Случайно-порождённые фракталы
• Управляющие конструкции
• Единицы измерения углов
• Анимация

	camera <атрибуты камеры>;
	light <атрибуты источника света1>;
	light <атрибуты источника света2>;
	...
	background(r,g,b,l); // цвет/яркость фона
	
	<формулы, отображения, подстановки>
	set s1 = <структура множества1>;
	set s2 = <структура множества2>;
	...
	build <структура множества3> <материал1>;
	build <структура множества4> <материал2>;

	camera  position (0,0,-80) vertical(0,1,0) fov(50);
	light   color (0,1,0)   position (1, 1,-3) shadows(0);
	light   color (1, 1, 0) position (3,-1,-1) shadows(0);
	ambient(1,1,1,.05);
	background(0,1,1,0.5); // цвет фона

	s=sqrt(3);
	f1 := translate(1/2, 1/2/s,0)*scale(1/s)*rotate(0,0,-1,150);
	f2 := translate(1,0,0)*scale(1/s)*rotate(0,0,-1,-150);
	f3 := translate(-1/2,s/2,0)*scale(s)*rotate(0,0,-1,30);
	f4 := translate(-1/2,-s/2,0)*scale(s)*rotate(0,0,-1,-90);
	f5 := translate(1,0,0)*scale(s)*rotate(0,0,-1,150);

	set KochCurve = (f1 + f2) KochCurve; // задание кривой Коха
	set Snowflake = (f3 + f4 + f5) KochCurve;
	build Snowflake;

Примечание: для пояснения различия между знаком присваивания '=' и знаком ':=' см. раздел подстановки.

Множества и отображения

Множества в программе задаются уравнениями вида: set S = f1(S) + f2(S) + ... + fn(S); Здесь S обозначает множество в 3-х мерном пространстве, знак '+' обозначает объединение множеств, и f1,...,fn - аффинные или мёбиусовы отображения множеств в трёхмерном пространстве, каждое из которых задаётся, как композиция базовых отображений.

Заметим, что математики обозначают объединение знаком ∪, т.е. правильная математическая запись приведённого выше уравнения: S = f1(S) ∪ f2(S) ∪ ... ∪ fn(S). Программа (исторически) использует знак плюса из-за ограничений клавиатуры и таблицы символов (ASCII).

Композиция отображений обозначается знаком суперпозиции '*'. Например translate(tx,ty,tz) * scale(k) * M означает сжать множество M с коэффициентом сжатия k и сдвинуть затем на вектор (tx,ty,tz).. Знак суперпозиции отображений можно опускать. Более того, работает ассоциативность операций '+' и '*', т.е. запись f1*(f2+f3) эквивалентна f1*f2+f1*f3.
Ассоциативность работает также с множествами, например, запись f1(S)+f2(S) эквивалентна (f1+f2)S.

Пример отображения:

	f1 := translate(-1,0,0) * scale(1/2);

Пример задания множества (отрезка [-1,1]):

	Segment = scale(0.5) * (translate(1,0,0) + translate(-1,0,0)) Segment;

Освещённость сцены рассчитывается широко известным методом трассировки лучей (ray-tracing), который требует чтобы были заданы источники света и отражающие свойства поверхности объектов (цвет, зеркальность и т.п.)

Цвет/яркость в программе задаются в виде (r,g,b,lum), где r,g,b - цвет, lum - яркость.
Параметр lum можно не указывать в этом случае lum=1.

• Программа поддерживает 3 типа источников света: Лампа, Прожектор, Солнце (точечный, направленный и параллельный источники).
• Добавить источник в сцену можно указав слово light и перечислив после него соответствующие атрибуты.
• Тип источника определится автоматически по заданным атрибутам.
• Количество источников в сцене может быть произвольным, при этом они могут быть разных типов.

Свойства поверхности задаются после команды build. Так как слово build может встречаться несколько раз, имеется возможность строить в одной сцене объекты с разными свойствами поверхности.

Свойство	Примечания	Описание
ambient(r,g,b,lum)	Аргументы можно задать в виде (r,g,b) или (lum)	Устанавливает цвет/яркость фоновой составляющей.
diffuse(r,g,b,lum)		Устанавливает цвет/яркость рассеянной составляющей.
specular(r,g,b,lum)		Устанавливает цвет/яркость зеркальной составляющей.
color(r,g,b)	для простоты	Задает цвет фоновой и рассеянной составляющей.Зеркальная устанавливается в (1,1,1).
metall(r,g,b)		Задает металлическую поверхность : устанавливает цвет рассеянной и зеркальной составляющей.

	<name> := <value>;

	sum := a + b;
	result = sum * 3;

	 result = a + b * 3;

• Имена переменных могут состоять из символов a-z,A-Z и подчёркивания "_"
  
• Вещественные функции:
   ln(x), exp(x), sqrt(x), abs(x), sign(x), sin(x), cos(x), tan(x), atan(x)
   atan2(y,x), arg(x,y) - эти две функции возвращают arctg(y/x)
   rnd(x) - случайное вещественное число на отрезке [0,x]
  
• Поддерживаемые вещественные, логические и битовые операции:
   = += -= *= /= + - * / , () ?: ++ -- == != < <= > >=
  
• Константы: PI и E.
  

• При построении, всему множеству, каждой его порции, каждой подпорции и т.п. сопоставляется псевдослучайное число. Число соответсвующее всему множеству можно задать вызвав перед оператором build функцию randState(аргумент), где вещественный аргумент лежит на отрезке [0,1]. Например: randState(rnd(1));
• Оператор (...)%n , где n - целое число, выбирает из скобок n отображений (или n порций), остальные выкидывает. Для выбора использует псевдослучайное число соотвествующее порции, которая дробится.
  Пример: (f1+f2+f3)%2.
• В операторе (...)%n после каждого отображения можно в фигурных скобках указать вес отображения (вещественное число большее нуля). Вероятность, с которой это отображение будет выбираться, вычисляется, как вес отображения делённый на сумму весов. Если вес не указан, он полагается равным единице.
  Например: (f1{2}+f2{3})%1
• При дроблении некоторой порции, по умолчанию псевдослучайное число передаётся её подпорциям без изменений. Но если встретилась конструкция f|m, то "случайное" число для подпорции, полученной применением отображения f, изменяется способом m, точнее изменяется под действием псевдослучайного генератора, зависящего от параметра m. Так, если у двух отображений номер m совпадает (например, в конструкции (f1|1+f2|1) ), то соответсвующие подпорции, получаемые под действием отображений f1,f2, получат одинаковое псевдослучайное число, и будут дробиться одинаковым образом.

• { оператор1; оператор2; ... }
  Составной оператор. Выполняет последовательность операторов, расположенных в фигурных скобках.
• if(выражение) оператор1; [ else оператор2;]
  Выполняет оператор1, если выражение отлично от нуля, иначе выполняет оператор2. Раздел else необязателен. Вместо любого из операторов можно использовать составной оператор.
• for(инициализация; выражение; итерация) тело;
  Сначала выполняется инициализация. Затем, в цикле вычисляется выражение и пока оно отлично от нуля выполняются тело цикла и итерация.
• while(условие) тело;
  Пока условие отлично от нуля, выполняется тело цикла.
• do { тело; } while(условие);
  Выполяет тело цикла, затем проверяет условие, и если оно отлично от нуля, снова выполнянет тело, затем снова проверяет условие и т.д.
• echo <переменные и строки>;
  Печатает в лог вывода переменные и текст, размещённый в двойных кавычках. Текст и имена переменных должны разделяться пробелом.